Bug présent dans le launcher de Dofus

Discutez de tout, de rien, du nAiO, de Dofus, de Wakfu, etc...

Bug présent dans le launcher de Dofus

Messagepar ZDS » 30 Juil 2015, 18:13

Bonjour,

Ce message est à l'attention des gens qui, comme Boulowok, rencontrent des soucis avec l'Uplauncher de Dofus :
  • En cliquant sur le bouton "Jouer", les fenêtres ne s'ouvrent pas
  • En cliquant sur le bouton "Jouer", l'uplauncher se réduit sans ouvrir le client de jeu
  • En tapant le raccourci Control+Chiffre pour ouvrir N fenêtres d'un coup, ça ne marche pas ou pas de suite
  • Le jeu rame à mort quand enfin on loggue une fenêtre
  • Plein de processus Dofus.exe avec peu de RAM dans le gestionnaire de tâches, bien plus qu'il n'y a de comptes à l'écran
Pour info, ce bug vient de l'Uplauncher et non du nAiO, c'est donc un problème attribué à Ankama Games. Mais voici un petit programme qui peut vous aider en attendant que le studio y fasse quelque chose : son but est très simple, tuer les processus parasites Dofus.exe (ceux qui ont peu de RAM et ne sont attribués à aucune fenêtre à l'écran) et ainsi arrêter de ramer comme un fou en voulant jouer à Dofus.

Voici le lien vers la version compilée du programme "Kill Bad Dofus" : http://files.naio.fr/.../Kill Bad Dofus.exe
Et voici son code source : http://files.naio.fr/.../Kill Bad Dofus.au3
Vous pouvez aussi le consulter ici même :
Code: Tout sélectionner
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=N:\Workspaces\nAiO v2\trunk\src\Images\Connexion\Defaut.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

; Constantes
Global Const $OK = "OK", $TITLE = "Kill Bad Dofus", $EMPTY_2D[1][2] = [[0]]

; Initialisation
Local $processus = ProcessList("Dofus.exe")
If @error Then $processus = $EMPTY_2D
Local $windows = WinList("[REGEXPTITLE:^[^\(\)]*$; CLASS:ApolloRuntimeContentWindow]")
If @error Then $windows = $EMPTY_2D

; Traitement
For $i = 1 To $processus[0][0]
   Local $pid = $processus[$i][1]
   For $j = 1 To $windows[0][0]
      Local $window = $windows[$j][1]
      If WinGetProcess($window) = $pid Then
         $processus[$i][0] = $OK
         ExitLoop
      EndIf
   Next
   If $processus[$i][0] <> $OK Then ProcessClose($processus[$i][1])
Next
Sleep(1000)

; Vérification
Local $found = 0, $count = 0
For $i = 1 To $processus[0][0]
   $count = $count + ($processus[$i][0] <> $OK ? 1 : 0)
   $found = $found + ($processus[$i][0] <> $OK And ProcessExists($processus[$i][1]) ? 1 : 0)
Next

; Message
TrayTip($TITLE, _
   "Nombre de processus : "&$processus[0][0]&@CRLF& _
   "Nombre de fenêtres : "&$windows[0][0]&@CRLF& _
   "Processus parasites : "&$count&@CRLF& _
   @CRLF& _
   ($found = 0 _
      ? "Tous les processus parasites"&@CRLF&"ont bien été coupés" _
      : "Il reste "&$found&" processus parasite"&($found>1?"s":"") _
   ), 30 _
   , ($found=0?1:3))
Sleep(5000)

Exit

Gardez à l'esprit que ce n'est en aucun cas un module du nAiO, simplement un petit programme que je vous propose pour vous dépanner en attendant une vraie correction de la part d'Ankama.

A bientôt !
Avatar de l’utilisateur
ZDS
Fondateur [Equipe nAiO]
 
Messages: 526

Retourner vers Discussions / Blablazone

Qui est en ligne

Utilisateurs parcourant ce forum: Aucun utilisateur enregistré et 6 invités